/**
* Connects a flash movie to the FlashDevelop program.
* Ported to AS3 by Keith Peters - http://www.bit-101.com/
* @author Mika Palmu
* @version 2.7
*/

package org.flashdevelop.utils
{
   import flash.net.XMLSocket;
   import flash.events.DataEvent;
   import flash.events.Event;
   import flash.events.IOErrorEvent;
   import flash.events.SecurityErrorEvent;
   import flash.xml.XMLDocument;
   import flash.xml.XMLNode;
   import flash.utils.setInterval;

   public class FlashConnect3
   {
      /**
      * Variables
      */
      private static var socket:XMLSocket;
      private static var messages:Array;
      private static var interval:Number;
      private static var swfUrl:String;
      public static var status:Number = 0;
      public static var host:String = "localhost";
      public static var port:Number = 6969;

      /**
      * Constants
      */
      public static const INFO:Number = 0;
      public static const DEBUG:Number = 1;
      public static const WARNING:Number = 2;
      public static const ERROR:Number = 3;
      public static const FATAL:Number = 4;

      /**
      * Opens the connection to the FlashDevelop program.
      */
      public static function initialize():void
      {
         messages = new Array();
         socket = new XMLSocket();
         socket.addEventListener(DataEvent.DATA, onData);
         socket.addEventListener(Event.CONNECT, onConnect);
         socket.addEventListener(IOErrorEvent.IO_ERROR, onIOError);
         socket.addEventListener(SecurityErrorEvent.SECURITY_ERROR, onSecurityError);
         interval = setInterval(sendStack, 50);
         socket.connect(host, port);
      }

      public static function onData(event:DataEvent):void
      {
         FlashConnect3.status = 1;
         FlashConnect3.onReturnData();
      }

      public static function onConnect(event:Event):void
      {
         FlashConnect3.status = 1;
         FlashConnect3.onConnection();
      }

      public static function onReturnData():void
      {

      }

      public static function onConnection():void
      {

      }

      public static function onIOError(event:IOErrorEvent):void
      {
         FlashConnect3.status = -1;
         FlashConnect3.onConnection();
      }

      public static function onSecurityError(event:SecurityErrorEvent):void
      {
         FlashConnect3.status = -1;
         FlashConnect3.onConnection();
      }

      /**
      * Sends all messages in message stack to FlashDevelop.
      */
      private static function sendStack():void
      {
         if (messages.length > 0 && status == 1)
         {
            var message:XMLDocument = new XMLDocument();
            var rootNode:XMLNode = message.createElement("flashconnect");
            while (messages.length != 0)
            {
               var msgNode:XMLNode = XMLNode(messages.shift());
               rootNode.appendChild(msgNode);
            }
            message.appendChild(rootNode);
            socket.send(message);
         }
      }

      /**
      * Adds a custom message to the message stack.
      */
      public static function send(message:XMLNode):void
      {
         if (messages == null) initialize();
         messages.push(message);
      }

      /**
      * Adds a trace command to the message stack.
      */
      public static function trace(msg:String, state:Number=FlashConnect3.DEBUG):void
      {
         var msgNode:XMLNode = new XMLNode(1, null);
         var txtNode:XMLNode = new XMLNode(3, escape(msg));
         msgNode.attributes.state = state;
         msgNode.attributes.cmd = "trace";
         msgNode.nodeName = "message";
         msgNode.appendChild(txtNode);
         send(msgNode);
      }

   }
}

package
{
   import flash.display.Sprite;
   import flash.display.StageAlign;
   import flash.display.StageScaleMode;
   import org.flashdevelop.utils.*
   // or import org.flashdevelop.utils.FlashConnect3
   public class App extends Sprite
   {
      public function App()
      {
         init();
      }
      
      private function init():void
      {
         stage.scaleMode = StageScaleMode.NO_SCALE;
         stage.align=StageAlign.TOP_LEFT;
         FlashConnect3.trace("grrr....")

      }
   }
}

-library-path+=../../frameworks/locale/{locale}
-source-path+=locale/{locale} -locale=en_US